//RFM12 Transmitter
//(c) 2012 www.loetstelle.net
//Verwendung nur zum privaten Gebrauch.



.include "m8def.inc"

.equ FLAG_USART_RCV= 0
.equ FLAG_INT0 = 1
.equ FLAG_SENDING = 2
.equ FLAG_IRQ_COUNTER = 3
.equ FLAG_POWER_UP = 4
.equ FLAG_DO_INIT = 5
.equ FLAG_INITIALIZED = 6
.equ FLAG_TX_TIMEOUT = 7

.equ LED_DDR = DDRC
.equ LED_PIN = 5



.EQU RFM12_CLOCK= 0
.EQU RFM12_DATA_IN = 1
.EQU RFM12_DATA_OUT = 2
.EQU RFM12_NSEL = 3

.EQU RFM12_PORT = PORTC
.EQU RFM12_PINS = PINC
.EQU RFM12_DDR = DDRC
.EQU MAX_IRQ_COUNTER = 50
.EQU MAX_TX_WATCHDOG = 10






.def sreg_temp=r1
.def temp1=r16
.def temp2=r17
.def temp3 = r18
.def flags = r19
.def rcv_byte = r20
.def tx_ptr = r21
.def irq_counter = r22
.def tx_watchdog = r23






//Usart 115200 kBit per Second /7.37 MHz Quarz
.equ BAUDRATE_REGISTER = 3



.org $0000
      rjmp main

.org INT0Addr

      rjmp INT0_Handler

.org URXCADDR
        rjmp USART_RX_HANDLER


.org OVF1Addr
      rjmp OVF1Handler





.org int_vectors_size*2
    
main:

        ldi temp1,low(ramend)
        out spl,temp1
        ldi temp1,high(ramend)
        out sph,temp1
        clr flags
        


        rcall usart_init
        rcall int0_init
        rcall timer1_init;

        rcall RFM12_Port_INIT

        

        ldi zl,low(MESSAGE_HELLO*2)
        ldi zh,high(MESSAGE_HELLO*2)
        rcall usart_message
        rcall usart_crlf
               
        sei


endless:
        sbrc flags,FLAG_USART_RCV
        rcall usart_rcv_handler
        nop
        sbrc flags,FLAG_INT0
        rcall flaghandler_int0
        nop
        sbrc flags,FLAG_IRQ_COUNTER
        rcall flaghandler_irq_counter
        nop
        sbrc flags,FLAG_DO_INIT
        rcall flaghandler_do_init
        nop
        sbrc flags,FLAG_TX_TIMEOUT
        rcall flaghandler_tx_timeout
        nop


        

        rjmp endless

flaghandler_tx_timeout:
        cbr flags,(1<<FLAG_TX_TIMEOUT)

        rcall RFM12_hardreset
        //Neuen Initialisierungszyklus starten
        cbr flags,(1<<FLAG_POWER_UP)

        
        ret




flaghandler_do_init:
        cbr flags,(1<<FLAG_DO_INIT)
        rcall rfm12_status
        rcall rfm12_init
        sbr flags,(1<<FLAG_INITIALIZED)
        ldi temp1,'i'
        
        rcall usart_transmit
        rcall usart_crlf
        ret
        


flaghandler_irq_counter:
        cbr flags,(1<<FLAG_IRQ_COUNTER)
        sbrc flags,FLAG_INITIALIZED
        rcall RFM12_SEND
        ret


flaghandler_int0:
        cbr flags,(1<<FLAG_INT0)
        sbrc flags,FLAG_SENDING
        rcall RFM12_send_next
        nop
        
        sbic pind,2
        rjmp exit_flaghandler_int0

        rcall rfm12_cancel
        rcall rfm12_status
        ldi temp1,'#'
        rcall usart_transmit
        ret


exit_flaghandler_int0:

        ret
            


usart_rcv_handler:
        cbr flags,(1<<FLAG_USART_RCV)
        cpi rcv_byte,'r'
        brne check1
        rjmp RFM12_softreset


check1:
        cpi rcv_byte,'s'
        brne check2 
        rjmp RFM12_status
             
check2:
        cpi rcv_byte,'c'
        brne check3
        rjmp RFM12_set_clock

check3:
        cpi rcv_byte,'i'
        brne  check4
        rjmp init
check4:
        cpi rcv_byte,'t'
        brne check5
        rjmp rfm12_send

check5:
        cpi rcv_byte,'x'
        brne check6
        rjmp rfm12_cancel

        
check6: cpi rcv_byte,'h'
        brne check7
        rjmp rfm12_hardreset




check7:
        ret

rfm12_hardreset:
        cbi portd,3
        sbi ddrd,3
        nop
        nop
        nop
        nop
        nop
        cbi ddrd,3
        ldi temp1,'H'
        rcall usart_transmit
        rcall usart_crlf
        ret



RFM12_send_next:
        clr temp1
        ldi zl,low(preambel*2)
        ldi zh,high(preambel*2)
        add zl,tx_ptr
        adc zh,temp1
        lpm temp2,z+
        tst temp2
        breq send_end
        inc tx_ptr

        ldi temp1,$b8
        rcall RFM12_command
        lpm temp1,z
        rcall usart_transmit
        lpm temp2,z
        tst temp2
        breq send_end
        ret

send_end:
        cbr flags,(1<<FLAG_SENDING)
        cbi LED_DDR,LED_PIN


        ldi temp1,$82
        ldi temp2,$01
        rcall RFM12_command
        ret






rfm12_cancel:
        cbi LED_DDR,LED_PIN
        cbr flags,(1<<FLAG_SENDING)
        ldi temp1,$b8
        ldi temp2,$aa
        rcall RFM12_command
        ldi temp1,$82
        ldi temp2,$01
        rcall RFM12_command
        rcall RFM12_status
        ldi temp1,'X'
        rcall usart_transmit
        rcall usart_crlf
        ret




RFM12_softreset:
        ldi temp1,$fe
        ldi temp2,$00
        rcall RFM12_command
        ldi temp1,'R'
        rcall usart_transmit
        rcall usart_crlf
        ret


init:
        rcall RFM12_init
        ldi temp1,'I'
        rcall usart_transmit
        rcall usart_crlf

        ret


RFM12_set_clock:
        
        ldi temp1,$c0
        ldi temp2,0b01100000
        rcall rfm12_command
        ldi temp1,'C'
        rcall usart_transmit
        rcall usart_crlf
        ret


        
    
RFM12_status:
        ldi temp1,':'
        rcall usart_transmit

     
        ldi temp1,$00
        ldi temp2,$00
        rcall RFM12_command
        push temp2
        push temp1

        push temp2
        rcall usart_writehex
        pop temp1
        rcall usart_writehex
        rcall usart_space
        pop temp1
        rcall usart_writebin
        rcall usart_space
        pop temp1
        rcall usart_writebin
        rcall usart_space
        ldi temp1,'0'
        sbic pind,2
        ldi temp1,'1'
        rcall usart_transmit


        rcall usart_crlf
        ret




rfm12_init:

        //CLOCK auf 2MHz
        ldi temp1,$c0
        ldi temp2,$40
        rcall rfm12_command
        
            
        //433MHZ, Enable Fifo, Enable Data Register, Capacitor 12.5pF
        ldi temp1,$80
        ldi temp2,$d7
        rcall rfm12_command
        
        
        //Set Frequency 434MHz
        ldi temp1,$A6
        ldi temp2,$40
        rcall rfm12_command
        
        //set Data Rate, $47 = 4.8KBit/s
        ldi temp1,$c6
        ldi temp2,$47
        rcall rfm12_command
        
        //Pin16 VDI Output,VDI Fast,BW 134,LNA Gain 0DB,RSSI -103DB
        ldi temp1,$94
        ldi temp2,$a0
        rcall rfm12_command
        
        //Data Filter CR Auto,Digital Filter,DQD Thresold 4
        ldi temp1,$c2
        ldi temp2,$ac
        rcall rfm12_command

        //Fifo 8 Bit, Disable High sensitive Reset
        ldi temp1,$ca
        ldi temp2,$81
        rcall rfm12_command
        
        //AFC Keep only,Enable Offset Register, Enable AFC
        ldi temp1,$c4
        ldi temp2,$83
        rcall rfm12_command
        
        //Modulation Polarity 0,135KHz Modulation, 0DB Output Power
        ldi temp1,$98
        ldi temp2,$50
        rcall rfm12_command
        //Disable Wakeup Timer
        ldi temp1,$e0
        ldi temp2,$00
        rcall rfm12_command
        
        //Disable Low Duty Cycle
        ldi temp1,$c8
        ldi temp2,$00
        rcall rfm12_command
        
        
        ret

RFM12_SEND:
        sbr flags,(1<<FLAG_SENDING)
        clr tx_watchdog
        sbi LED_DDR,LED_PIN
        clr tx_ptr
        ldi temp1,$82
        ldi temp2,$39
        rcall rfm12_command
        
        
        ldi temp1,'T'
        rcall usart_transmit
        rcall usart_crlf


        ret


int0_init:
        ldi temp1,(1<<ISC01)|(0<<ISC00)
        out mcucr,temp1
        ldi temp1, (1<<INT0)
        out GICR,temp1
        ret

            

      

usart_space:
        ldi temp1,' '
        rcall usart_transmit
        ret


usart_message:
        lpm temp1,z+
        tst temp1
        breq exit_usart_message
        rcall usart_transmit
        rjmp usart_message
exit_usart_message:
        ret


usart_writehex:
	rcall bin2hex
	rcall usart_transmit
	mov temp1,temp2
	rcall usart_transmit
	ret

usart_writebin:
    ldi temp3,$08
    mov temp2,temp1

write_bin_loop:    
    ldi temp1,'0'
    tst temp2
    brpl no_one
    ldi temp1,'1'

no_one:
    rcall usart_transmit
    lsl temp2
    dec temp3
    brne write_bin_loop
    ret





bin2hex:
	mov  temp2,temp1
	swap temp1
	andi temp1,$0f
	subi temp1,-48
	cpi temp1,$3a
	brlo nochar3
	subi temp1,-39
		  
nochar3:
	andi temp2,$0f
	subi temp2,-48
	cpi temp2,$3a
	brlo nochar4
	subi temp2,-39

nochar4:
	ret


usart_crlf:
        ldi temp1,$0d
        rcall usart_transmit
        ldi temp1,$0a
        rcall usart_transmit
        ret


usart_transmit:
        cli
        sbis UCSRA,UDRE
        rjmp USART_Transmit
        out UDR,temp1
        sei

exit_usart_transmit:
        ret

        
usart_init:
        ldi temp1, high(BAUDRATE_REGISTER)
        out UBRRH,temp1
        ldi temp1, low(BAUDRATE_REGISTER)
        out UBRRL,temp1
        ldi temp1, (1<<RXCIE)|(1<<TXEN)|(1<<RXEN)
        out UCSRB,temp1
        ldi temp1,(1<<URSEL)|(1<<UCSZ1)|(1<<UCSZ0)
        out UCSRC,temp1
        ret

usart_rx_handler:
        in sreg_temp,sreg
        push temp1
        in rcv_byte,udr
        sbr flags,(1<<FLAG_USART_RCV)
        pop temp1

        out sreg,sreg_temp
        reti

timer1_init:
         //prescaler  8
        ldi temp1,0b00000010
        out TCCR1b,temp1
        ldi temp1,(1<<TOIE1)
        out timsk,temp1
        ret



int0_handler:
        in sreg_temp,sreg
        sbr flags,(1<<FLAG_INT0)
        out sreg,sreg_temp
        reti

OVF1Handler:
        in sreg_temp,sreg
        sbrc flags,FLAG_SENDING
        rcall tx_watchdog_handler
        inc irq_counter
        cpi irq_counter,MAX_IRQ_COUNTER
        brne exit_OVF0Handler
        clr irq_counter
        sbr flags,(1<<FLAG_IRQ_COUNTER)
        sbrs flags,FLAG_POWER_UP
        sbr flags,(1<<FLAG_DO_INIT)
        sbr flags,(1<<FLAG_POWER_UP)

        
exit_ovf0handler:        
        out sreg,sreg_temp
        reti

tx_watchdog_handler:
        inc tx_watchdog
        cpi tx_watchdog,MAX_TX_WATCHDOG
        brne exit_tx_watchdog_handler
        sbr flags,(1<<FLAG_TX_TIMEOUT)
exit_tx_watchdog_handler:
        ret



rfm12_command:
        cli
        cbi RFM12_PORT,RFM12_NSEL
        rcall rfm12_delay
        

        ldi temp3,$10
        

rfm12_transmit_loop:

        tst temp1
        brpl transmit_0
        sbi RFM12_PORT,RFM12_DATA_IN
        rjmp continue_rfm12_transmit

transmit_0:
        cbi RFM12_PORT,RFM12_DATA_IN
        
      

        
continue_rfm12_transmit:
        sbi RFM12_PORT,RFM12_CLOCK
        rcall rfm12_delay
        lsl temp2
        rol temp1
        
        sbic RFM12_PINS,RFM12_DATA_OUT
        ori temp2,$0b00000001
        
        cbi RFM12_PORT,RFM12_CLOCK
        rcall rfm12_delay
     

        dec temp3
        brne rfm12_transmit_loop
     
        rcall rfm12_delay


        sbi RFM12_PORT,RFM12_NSEL
        sei
        ret

RFM12_DELAY:
        ret
        




RFM12_PORT_INIT:
        ldi temp1,(1<<RFM12_CLOCK)|(1<<RFM12_DATA_IN)|(1<<RFM12_NSEL)
        out RFM12_DDR,temp1

        sbi RFM12_PORT,RFM12_NSEL
        ret
         

preambel:
        .db $aa,$aa,$aa,$2d,$d4,"01234567890abcdefgh",$aa,$aa,$aa,$00



message_hello:
        .db "Hallo !",$00