//(C) 2012 www.loetstelle.net
//Verwendung nur zum Privaten Gebrauch!
.include "tn24def.inc"

.equ FLAG_PACKET_RECEIVED=0
.equ FLAG_INT0 = 1
.equ FLAG_RECEIVING = 2
.equ FLAG_IRQ_COUNTER = 3
.equ FLAG_POWER_UP = 4
.equ FLAG_DO_INIT = 5
.equ FLAG_INITIALIZED = 6
.equ FLAG_RX_WATCHDOG = 7



.EQU RFM12_CLOCK= 4
.EQU RFM12_DATA_IN = 5
.EQU RFM12_DATA_OUT = 2
.EQU RFM12_NSEL = 3 //OK
.EQU RFM12_RESET = 6


.EQU RFM12_NIRQ = 2 //OK

.EQU LED_DDR = DDRB
.EQU LED_PORT = PORTB


.EQU LED_PIN = 1

.EQU RFM12_IRQ_PIN = PINB

.EQU RFM12_PORT = PORTA
.EQU RFM12_PINS = PINA
.EQU RFM12_DDR = DDRA
.EQU MAX_IRQ_COUNTER = 25
.EQU RX_PACKET_LENGTH = 16
.EQU MAX_RX_WATCHDOG = 50

.EQU OUT_1_DDR = DDRB
.EQU OUT_2_DDR = DDRA
.EQU OUT_3_DDR = DDRA
.EQU OUT_4_DDR = DDRA

.EQU OUT_1_PORT = PORTB
.EQU OUT_2_PORT = PORTA
.EQU OUT_3_PORT = PORTA
.EQU OUT_4_PORT = PORTA

.EQU OUT_1_PINS = PINB
.EQU OUT_2_PINS = PINA
.EQU OUT_3_PINS = PINA
.EQU OUT_4_PINS = PINA

.EQU OUT_1_PIN = 0
.EQU OUT_2_PIN = 0
.EQU OUT_3_PIN = 1
.EQU OUT_4_PIN = 7

.EQU CMD_ON = $44
.EQU CMD_OFF = $22
.EQU CMD_TOGGLE = $11



.def sreg_temp=r1
.def temp1=r16
.def temp2=r17
.def temp3 = r18
.def temp4 = r15
.def temp5 = r14

.def flags = r19
.def rcv_byte = r20
.def irq_counter = r21
.def rx_counter = r22
.def rx_watchdog_counter = r23








//Usart 115200 kBit per Second
.equ BAUDRATE_REGISTER = 3



.org $0000
      rjmp main

.org EXT_INT0Addr

     rjmp INT0_Handler





.org OVF0Addr
      rjmp OVF0Handler





.org int_vectors_size*2
    
main:

        ldi temp1,low(ramend)
        out spl,temp1

        clr flags
        rcall led_on
        


        rcall int0_init
        rcall timer0_init;

        rcall RFM12_Port_INIT
        rcall output_port_init

       

               
        sei


endless:
        sbrc flags,FLAG_INT0
        rcall flaghandler_int0
        nop
        sbrc flags,FLAG_IRQ_COUNTER
        rcall flaghandler_irq_counter
        nop
        sbrc flags,FLAG_DO_INIT
        rcall flaghandler_do_init
        nop
        sbrc flags,FLAG_RX_WATCHDOG
        rcall flaghandler_rx_watchdog
        nop
        sbrc flags,FLAG_PACKET_RECEIVED
        rcall flaghandler_packet_received

        ldi temp1,(1<<SM1)|(0<<SM0)|(0<<SE)|(1<<ISC01)|(0<<ISC00)
        out MCUCR,temp1
        sbrc flags,FLAG_INITIALIZED
        sleep
        nop

        

        rjmp endless

flaghandler_packet_received:
        cbr flags,(1<<flag_packet_received)

        rcall crc8
        lds temp2,received_crc
        cp temp1,temp2
        breq packet_ok

        ret
packet_ok:
        
        rcall check_listen_address
        breq listen_address_ok
       
        ret

listen_address_ok:
   

        rcall check_listen_app
        breq listen_app_ok
        ret


listen_app_ok:        
        ldi xl,low(received_cmd)
        ldi xh,high(received_cmd)

        ld temp1,x+
        cpi temp1,CMD_ON
        breq on_1
        cpi temp1,CMD_OFF
        breq off_1
        cpi temp1,CMD_TOGGLE
        breq toggle_1
        rjmp process_2

on_1:   sbi OUT_1_PORT,OUT_1_PIN
        rjmp process_2

off_1:  cbi OUT_1_PORT,OUT_1_PIN
        rjmp process_2

toggle_1:  sbi OUT_1_PINS,OUT_1_PIN
        rjmp process_2



process_2:
        
        ld temp1,x+
        cpi temp1,CMD_ON
        breq on_2
        cpi temp1,CMD_OFF
        breq off_2
        cpi temp1,CMD_TOGGLE
        breq toggle_2
        rjmp process_3

on_2:   sbi OUT_2_PORT,OUT_2_PIN
        rjmp process_3

off_2:  cbi OUT_2_PORT,OUT_2_PIN
        rjmp process_3

toggle_2:  sbi OUT_2_PINS,OUT_2_PIN
        rjmp process_3

process_3:
        
        ld temp1,x+
        cpi temp1,CMD_ON
        breq on_3
        cpi temp1,CMD_OFF
        breq off_3
        cpi temp1,CMD_TOGGLE
        breq toggle_3
        rjmp process_4

on_3:   sbi OUT_3_PORT,OUT_3_PIN
        rjmp process_4

off_3:  cbi OUT_3_PORT,OUT_3_PIN
        rjmp process_4

toggle_3:  sbi OUT_3_PINS,OUT_3_PIN
        rjmp process_4


process_4:
        
        ld temp1,x+
        cpi temp1,CMD_ON
        breq on_4
        cpi temp1,CMD_OFF
        breq off_4
        cpi temp1,CMD_TOGGLE
        breq toggle_4
        ret

on_4:   sbi OUT_4_PORT,OUT_4_PIN
        ret

off_4:  cbi OUT_4_PORT,OUT_4_PIN
        ret

toggle_4:  sbi OUT_4_PINS,OUT_4_PIN
        ret






    





flaghandler_rx_watchdog:
        cbr flags,(1<<FLAG_RX_WATCHDOG)
        rcall RFM12_end_receive
        rcall RFM12_hardreset
        cbr flags,(1<<FLAG_POWER_UP)
        ret




flaghandler_do_init:
        cbr flags,(1<<FLAG_DO_INIT)
        rcall rfm12_read_status
        rcall rfm12_init
        rcall rfm12_read_status

        sbr flags,(1<<FLAG_INITIALIZED)
        rcall led_off
        rcall RFM12_start_receive
        ret
        


flaghandler_irq_counter:
        cbr flags,(1<<FLAG_IRQ_COUNTER)
        sbrc flags,FLAG_INITIALIZED
        
        ret


flaghandler_int0:
        cbr flags,(1<<FLAG_INT0)
        sbrc flags,FLAG_RECEIVING
        rcall do_receive
        nop
        ret
            
do_receive:
       
        rcall rfm12_fifo
        brne exit_do_receive

        rcall led_on





            

       

        ldi temp1,$b0
        ldi temp2,$00
        rcall rfm12_command
        ldi yl,low(received_packet)
        ldi yh,high(received_packet)
        clr temp1
        add yl,rx_counter
        adc yh,temp1
        st y,temp2
        inc rx_counter
        

       
      
       cpi rx_counter,RX_PACKET_LENGTH
       brne exit_do_receive
       sbr flags,(1<<flag_packet_received)
       rcall RFM12_end_receive


        rcall RFM12_start_receive
       

exit_do_receive:
        ret




        



    


rfm12_start_receive:
        
        clr rx_counter
        clr rx_watchdog_counter
    

        rcall rfm12_receive

        ret


        



rfm12_receive:
        //Enable receiver,Enable Baseband,Crystal ON
        ldi temp1,$82
        ldi temp2,$c8
        rcall rfm12_command
        //8 Bit Fifo, clear FF, Disable High Sensitive Reset
        ldi temp1,$ca
        ldi temp2,$81
        rcall rfm12_command
        //8Bit Fifi, SET FF, Disable High Sensitive Reset
        ldi temp1,$ca
        ldi temp2,$83
        rcall rfm12_command
        sbr flags,(1<<FLAG_RECEIVING)
        

        ret

rfm12_end_receive:
         //Turn off Receiver, Turn on Crystal, Disable Clock Output
        ldi temp1,$82
        ldi temp2,$00
        rcall rfm12_command
        cbr flags,(1<<FLAG_RECEIVING)
        rcall led_off
        ret



rfm12_hardreset:
        cbi RFM12_PORT,RFM12_RESET
        sbi RFM12_DDR,RFM12_RESET
        nop
        nop
        nop
        nop
        nop
        cbi RFM12_DDR,RFM12_RESET
        ret


RFM12_read_status:
             
        ldi temp1,$00
        ldi temp2,$00
        rcall RFM12_command
        ret

RFM12_init:

        //CLOCK auf 2MHz
        ldi temp1,$c0
        ldi temp2,$40
        rcall rfm12_command
        
            
        //433MHZ, Enable Fifo, Enable Data Register, Capacitor 12.5pF
        ldi temp1,$80
        ldi temp2,$d7
        rcall rfm12_command
        
        
        //Set Frequency 434MHz
        ldi temp1,$A6
        ldi temp2,$40
        rcall rfm12_command
        
        //set Baud Rate
        ldi temp1,$c6
        ldi temp2,$47
        rcall rfm12_command
        
        //Pin16 VDI Output,VDI Fast,BW 134,LNA Gain 0DB,RSSI -103DB
        ldi temp1,$94
        ldi temp2,$a0
       
        rcall rfm12_command
        
        //Data Filter CR Auto,Digital Filter,DQD Thresold 4
        ldi temp1,$c2
        ldi temp2,$ac
        rcall rfm12_command
        
        //Fifo 8 Bit, Disable High sensitive Reset
        ldi temp1,$ca
        ldi temp2,$81
        rcall rfm12_command
        
        //AFC Keep only,Enable Offset Register, Enable AFC
        ldi temp1,$c4
        ldi temp2,$83
        rcall rfm12_command
        
        //Modulation Polarity 0,135KHz Modulation, 0DB Output Power
        ldi temp1,$98
        ldi temp2,$50
        rcall rfm12_command
        //Disable Wakeup Timer
        ldi temp1,$e0
        ldi temp2,$00
        rcall rfm12_command
        
        //Disable Low Duty Cycle
        ldi temp1,$c8
        ldi temp2,$00
        rcall rfm12_command
        
        
        ret

LED_ON:
        sbi LED_DDR,LED_PIN
        cbi LED_PORT,LED_PIN
        ret

LED_OFF:sbi LED_DDR,LED_PIN
        sbi LED_PORT,LED_PIN
        ret






int0_init:
        ldi temp1,(1<<ISC01)|(0<<ISC00)
        out mcucr,temp1
        ldi temp1, (1<<INT0)
        out GICR,temp1
        ret

            



timer0_init:
         //prescaler  8
        ldi temp1,0b00000101
        out TCCR0b,temp1
        ldi temp1,(1<<TOIE0)
        out timsk0,temp1
        ret



int0_handler:
        in sreg_temp,sreg
        sbr flags,(1<<FLAG_INT0)
        out sreg,sreg_temp
        reti

OVF0Handler:
        in sreg_temp,sreg
        sbrc flags,FLAG_RECEIVING
        //rcall rx_watchdog_handler
        
        nop
        inc irq_counter
        cpi irq_counter,MAX_IRQ_COUNTER
        brne exit_OVF0Handler
        clr irq_counter
        sbr flags,(1<<FLAG_IRQ_COUNTER)
        sbrs flags,FLAG_POWER_UP
        sbr flags,(1<<FLAG_DO_INIT)
        sbr flags,(1<<FLAG_POWER_UP)

        
exit_ovf0handler:        
        out sreg,sreg_temp
        reti

rx_watchdog_handler:
        inc rx_watchdog_counter
        cpi rx_watchdog_counter,MAX_RX_WATCHDOG
        brne exit_rx_watchdog_handler
        sbr FLAGS,(1<<FLAG_RX_WATCHDOG)
exit_rx_watchdog_handler:
        ret



rfm12_fifo:
       cli
       clr temp2
       cbi RFM12_PORT,RFM12_DATA_IN
       cbi RFM12_PORT,RFM12_CLOCK
       cbi RFM12_PORT,RFM12_NSEL
       sbic RFM12_PINS,RFM12_DATA_OUT
       inc temp2
       sbi RFM12_PORT,RFM12_NSEL
       tst temp2
       sei
       ret









rfm12_command:
        cli
        cbi RFM12_PORT,RFM12_NSEL
        rcall rfm12_delay
        

        ldi temp3,$10
        

rfm12_transmit_loop:

        tst temp1
        brpl transmit_0
        sbi RFM12_PORT,RFM12_DATA_IN
        rjmp continue_rfm12_transmit

transmit_0:
        cbi RFM12_PORT,RFM12_DATA_IN
        
      

        
continue_rfm12_transmit:
        sbi RFM12_PORT,RFM12_CLOCK
        rcall rfm12_delay
        lsl temp2
        rol temp1
        
        sbic RFM12_PINS,RFM12_DATA_OUT
        ori temp2,$0b00000001
        
        cbi RFM12_PORT,RFM12_CLOCK
        rcall rfm12_delay
     

        dec temp3
        brne rfm12_transmit_loop
     
        rcall rfm12_delay


        sbi RFM12_PORT,RFM12_NSEL
        sei
        ret

RFM12_DELAY:
        ret
        




RFM12_PORT_INIT:
        ldi temp1,(1<<RFM12_CLOCK)|(1<<RFM12_DATA_IN)|(1<<RFM12_NSEL)|(1<<LED_PIN)
        out RFM12_DDR,temp1

        sbi RFM12_PORT,RFM12_NSEL

        ret

OUTPUT_PORT_INIT:
        cbi OUT_1_PORT,OUT_1_PIN
        cbi OUT_2_PORT,OUT_2_PIN
        cbi OUT_3_PORT,OUT_3_PIN
        cbi OUT_4_PORT,OUT_4_PIN
        sbi OUT_1_DDR,OUT_1_PIN
        sbi OUT_2_DDR,OUT_2_PIN
        sbi OUT_3_DDR,OUT_3_PIN
        sbi OUT_4_DDR,OUT_4_PIN
        ret


check_listen_address:
        ldi zl,low(listen_address*2)
        ldi zh,high(listen_address*2)
        ldi xl,low(received_listen_address)
        ldi xh,high(received_listen_address)
        ldi temp3,$04

check_listen_address_loop:
        lpm temp1,z+
        ld temp2,x+
        cp temp1,temp2
        brne exit_check_listen_address
        dec temp3
        brne check_listen_address_loop

exit_check_listen_address:
        ret

check_listen_app:
        ldi zl,low(listen_app*2)
        ldi zh,high(listen_app*2)
        ldi xl,low(received_listen_app)
        ldi xh,high(received_listen_app)
        ldi temp3,$04

check_listen_app_loop:
        lpm temp1,z+
        ld temp2,x+
        cp temp1,temp2
        brne exit_check_listen_app
        dec temp3
        brne check_listen_app_loop

exit_check_listen_app:
        ret
                


CRC8: //Dallas-Style.....

	ldi temp1,15
    mov temp5,temp1
    ldi xl,low(received_packet)
    ldi xh,high(received_packet)

    clr	temp1 //Startwert auf 0


CRC8_GetByte:ld	temp4,X+		
	ldi	temp3,8		
    	
CRC8_DoBit:mov	temp2,temp4		
	eor	temp2,temp1		
	lsr	temp1			
	lsr	temp4			
	lsr	temp2			
	brcc CRC8_NoAdjustment			
	ldi	temp2,$8C
	eor	temp1,temp2
CRC8_NoAdjustment:
	dec	temp3			
    brne	CRC8_DoBit			
	dec	temp5			
	brne	CRC8_GetByte	
	ret	


//Debug....


RCV_TO_EEPROM:
      cli

     ldi temp1,$00
     ldi xl,low(received_packet)
     ldi xh,high(received_packet)


eepr_loop:     
     ld temp2,x+
     rcall EEPROM_Write
     inc temp1
     cpi temp1,16
     brne eepr_loop
     ret



EEPROM_write:
; Wait for completion of previous write
push temp1
EEPROM_WAIT:

sbic EECR, EEPE
rjmp EEPROM_wait
; Set Programming mode
ldi temp1, (0<<EEPM1)|(0<<EEPM0)
out EECR, temp1
pop temp1

clr temp3
out EEARH, temp3
out EEARL, temp1
; Write data (r19) to data register
out EEDR, temp2
; Write logical one to EEMPE
sbi EECR, EEMPE
; Start eeprom write by setting EEPE
sbi EECR, EEPE
ret

listen_app:
        .db "trmt"
listen_address:

        .db 192,168,0,1
     			


.dseg 





//16 Byte Packet:
received_packet:


received_listen_app:
        .byte 4


received_listen_address:
        .byte 4

received_cmd:
        .byte 4

        .byte 3

received_crc:
        .byte 1